bplus QBJS Proggies

Oh hey this is working now as I originally coded in QB64:



QB64 code port:
_Title "15 Squares Puzzle" 'b+ mod for QBJS 2022-02-19

'  2023-09-24 This is working from my QB64 code

Dim Shared As Integer board(4, 4)
Dim Shared As Integer r0, c0, d
Dim As Integer r, c, i, solved
Dim As String b, k
For r = 1 To 4
   For c = 1 To 4
       board(c, r) = c + (r - 1) * 4
   Next
Next
board(4, 4) = 0
c0 = 4
r0 = 4
Cls
For i = 0 To 50 * 4 * 4
   d = Val(Mid$("0358", Int(Rnd * 4) + 1, 1))
   handle
Next
While 1
   Locate 1, 1
   b = ""
   solved = 1
   For r = 1 To 4
       For c = 1 To 4
           If board(c, r) Then
               If board(c, r) <> c + (r - 1) * 4 Then
                   solved = 0
               End If
               b = b + Right$("   " + Str$(board(c, r)), 3) + " "
           Else
               b = b + "    "
           End If
       Next
       Print b
       b = ""
   Next
   Print
   If solved Then
       Locate 4 + 2, 2
       Print "Solved!"
       _Delay 5
       'End
   End If
   k = InKey$
   If Len(k) = 2 Then
       d = (Asc(Right$(k, 1)) - 72)
       handle
   End If
   _Limit 30
Wend

Sub handle
   Select Case d
       Case 3
           If c0 < 4 Then
               board(c0, r0) = board(c0 + 1, r0)
               board(c0 + 1, r0) = 0
               c0 = c0 + 1
           End If
       Case 5
           If c0 > 1 Then
               board(c0, r0) = board(c0 - 1, r0)
               board(c0 - 1, r0) = 0
               c0 = c0 - 1
           End If
       Case 0
           If r0 < 4 Then
               board(c0, r0) = board(c0, r0 + 1)
               board(c0, r0 + 1) = 0
               r0 = r0 + 1
           End If
       Case 8
           If r0 > 1 Then
               board(c0, r0) = board(c0, r0 - 1)
               board(c0, r0 - 1) = 0
               r0 = r0 - 1
           End If
   End Select
End Sub


Use up/down left/right arrow keys to move number blocks into space:
[qbjs]https://qbjs.org/?code=RGltIFNoYXJlZCBBcyBJbnRlZ2VyIGJvYXJkKDQsIDQpCtYicjAsIGMwLCBkxSDMGSwgYywgaSwgc29sdmXJH1N0cmluZyBiLCBrCkZvciByID0gMSBUbyA0CiAgICDEE2POE8QB5gCIYywgcikgPSBjICsgKHIgLSAxKSAqxyZOZXh0CsUF6wC0ID0gMApjMCA9IDQKcsYHQ2xzxXhpxBzEZTUwxETJSGQgPSBWYWwoTWlkJCgiMDM1OCIs5ADUKFJuZMQlKSArIDEsIDEpKcUvaGFuZGxlxnlXaGlsZSAxxRhMb2NhdGXFKsUQYiA9ICIixQvmARDkAOTpAPLvAQX7AQnEAUlm7QEQVGhlbs0g0yQ8PvABNdY37QCgMNEfRW5kIElm0RfkAN1iICsgUmlnaHQkKCIgICAiICvkAeskKOsAhiksIDPkAT8iIOYBCclWbHNl2VTETdAw7gCG5QF8yA1QcmludCBiyRDrAXjJKMUkxQpJZugA7u0BDucBvTQgKyAyLCAyz10iU8UzIeoAlV9EZWxheSA1yREnRW5kxQ3rAKtrID0gSW5LZXkkyHtMZW4oa+QCpDLOf+QBfChBc2Mo5wFQa+UCbyAtIDcy5gJ1xAHnAnnPZV9MaW1pdCAzMApXZW5kCgpTdWLMKlNlbGVjdCBDYXNlIOYAocQBxQ8z8AJjYzAgPPgCJ+cB1TAsIHIw5ADByBDmAxxyMOoAp9AyySL1AmDlA6vGJfwB8uUAseoBbsQB5gCxPuQDL/8Ase4AsS3/ALHKIv0AsS3/ALHkALHOPklmIHL/AWL0ALHEEOQBH/oAscki9QCx5QUGxiH/ALFlIDjNIuYAsf8BYvcAseQEdd0yxSL9ALH7AWLEC+YC2grFC3Vi[/qbjs]
Honestly this one takes practice to get use to using arrow keys instead of mouse to move "blocks" I will try to get my GUI mouser version going in QBJS because it plays way more natural! I liked this for brevity of code but obviously we paid a price here

I found this in reviewing my posts at Friends Of Basic:

Spinner

QB64 and QBJS:
'Option _Explicit
'_Title "Spinner" 'b+ 2021-06-18

' 2023-09-25 convert to QBJS

Dim As Long b, r, i
Dim a
Screen _NewImage(500, 500, 32)
Const rad = _Pi / 180
While 1
   Cls
   b = b + 5
   For r = 20 To 200 Step 20 ' tsh73 suggested fix for inner most
       a = b * r / 20
       For i = r - 15 To r
           arc 250, 250, i, a, 180
       Next
   Next
   _Display
   _Limit 5 ' slowed down for QBJS
Wend

Sub arc (xCenter, yCenter, arcRadius, dAStart, dAMeasure)
   'notes:
   'you may want to adjust size and color for line drawing
   'using angle measures in degrees to match Just Basic ways with pie and piefilled
   'this sub assumes drawing in a CW direction if dAMeasure positive

   'for Just Basic angle 0 degrees is due East and angle increases clockwise towards South

   'dAStart is degrees to start Angle, due East is 0 degrees

   'dAMeasure is degrees added (Clockwise) to dAstart for end of arc

   Dim rAngleStart, rAngleEnd, Stepper, lastX, lastY, rAngle, nextX, nextY
   rAngleStart = rad * dAStart
   rAngleEnd = rad * dAMeasure + rAngleStart
   Stepper = rad / (.1 * arcRadius) 'fixed
   lastX = xCenter + arcRadius * Cos(rAngleStart)
   lastY = yCenter + arcRadius * Sin(rAngleStart)
   For rAngle = rAngleStart + Stepper To rAngleEnd Step Stepper
       nextX = xCenter + arcRadius * Cos(rAngle)
       nextY = yCenter + arcRadius * Sin(rAngle)
       Line (lastX, lastY)-(nextX, nextY) 'int speeds things up
       lastX = nextX: lastY = nextY
   Next
End Sub


[qbjs]https://qbjs.org/?code=J09wdGlvbiBfRXhwbGljaXQKJ19UaXRsZSAiU3Bpbm5lciIgJ2IrIDIwMjEtMDYtMTgKCifEDjMtMDktMjUgY29udmVydCB0byBRQkpTCgpEaW0gQXMgTG9uZyBiLCByLCBpxRRhClNjcmVlbiBfTmV3SW1hZ2UoNTAwLCDFBTMyKQpDb25zdCByYWQgPSBfUGkgLyAxODAKV2hpbGUgMQogICAgQ2xzxQhiID0gYiArIDXFDkZvciByID0gMjAgVG8gMjAwIFN0ZXDEDycgdHNoNzMgc3VnZ2VzdGVkIGZpeCBmb3Ig5QDaIG1vc3TFQ8QBYcVVKiByIC8gMjDJF8ReaSA9IHIgLSAxNcRicskcxTdyYyAyNTAsxgVpLCBhLOUAuMggTmV4xmTJCV9EaXNwbGF5xg1MaW1pdCA1ICcgc2xvd2VkIGRvd27lAKTlAU9XZW5kCgpTdWLFaSh4Q2VudGVyLCB5yAlhcmNSYWRpdXMsIGRBU3RhcnTECU1lYXN1cmUpxWQnbm90ZXM6xgx5b3UgbWF5IHdhbuUBtWFkanVzdCBzaXplIGFuZCBjb2xvcuUAgGxpbmUgZHJhd2luZ8Y8dXNpbmcgYW5nbGUgbcZicyBpbiBkZWdyZWVzxE9tYXRjaCBKxFNCYXNpYyB3YXlzIHdpdGggcGnGYnBpZWZpbGxlZMZVdGhpcyBz5ADhc3N1bWVzyHPEWWEgQ1cgZGlyZWPlAqVpZuoA2yBwb3NpdGl2ZQrGR+QAsst35gClMOkAm2lzIGR1ZSBFYXN05QCFxiBpbmNyZWFzZXMgY2xvY2t3aXNlIHRvd2FyZHMgU291dGjHXecBWsVGx1F0byBzxRRBxEosyl5pc8p3yT/oALXLQWFkZGVkIChDyHkpxFNkQcZV5ADOZW5kIG9m5AHhxkfkA0VyxW7nAefGDUVuZCzlAvJw5AIPbGFzdFjGB1nIIiwgbmV4xBbEB1nFTMtI5ALcYWQgKugCP8sgRW7kA4zIHugAxCvMPsUux37HLC8gKC4xICrqApopICdmaXjnAfDlAKEgPSDnAsogK8ooICogQ29zKMte5gLAxDNZID3oAvTPM1NpbtIz5QQUxRXkAJXKHiAr6QCt5APK6QDmxBXIGukDu+UBNv8Aq8RBxnPIMv8Aqs8yTOQDZSjsAbYpLSjsAa8pICdpbnQgc3BlZWRzIHRoaW5ncyB1cMlB6AFQxTQ6xkPHD+YB6+UEeOUA5HViCg==[/qbjs]

Yep! dbox not the best code to show in QBJS, not only slower than QB64 but notice the beautiful cross pattern shadow! ;-)) I like it!

Well I am trying to have a set of proggies that work both in QB64 and QBJS without change.

It is interesting to see the arcs with square edges.

Let's see if I can rework spinner for both QB64 and QBJS. Currently my QBJS version sucks speed wise plus odd pset artifacts in QBJS a slight shaded cross interference pattern which might explain why dbox interrupted my monologue ;-)) Man! you get so use to doing monologues at forums of low activity that you start planning on things but then you get people heckling you with better ideas. Sheez what is this a forum or something? LOL

My pet peeve about using QB's circle keyword to do arcs. It sucks because it doesn't follow Trig functions, but few people can follow what I say because few people want to deal with Trig functions. This is BASIC for god's sake we don't do trig functions unless we absolutely have to because there is no other way! Oh god don't make me do math! LOL

I actually did Spinner to show off my Arc function and then dbox comes along and erases it. True the spinner program really doesn't pick up the difference between doing Arcs with Circle and my Arcs subroutine because it's all symmetric, so there's that.

WTH is bplus talking about?

Draw one arc say from 90 degrees to 90 + 45 = 135 degrees with my Arc sub, it would start at pi/2 which is due South in Basic Trig Sin and Cos.
And it would go to Pi(3/4) which is due SW or 7:30 on anyone's wrist watch from the 60's.

Now WTH does circle method do?
_Title "bplus pet peeve against circle arcs" ' b+ 2023-09-25
Screen _NewImage(680, 480, 12)
Print " A Tale of Two Arcs: that are drawn from Pi/2 to Pi*3/4"
Circle (340, 250), 200, 8
Color 14, 0
Print "             Here the Arc in question drawn with Circle method."
Circle (340, 250), 200, 14, _Pi(1 / 2), _Pi(3 / 4)
Color 9, 0
Locate 15, 1
Print "             Here is the Arc in question plotted out using Trig Functions:"
For angle = _Pi(1 / 2) To _Pi(3 / 4) Step _Pi(1 / 180)
   Circle (340 + 200 * Cos(angle), 250 + 200 * Sin(angle)), 2, 9
Next
Color 15
Sleep




There is a bit of a difference! If you are like me use to plotting allot with Sin and Cos, just view my history of proggies!, then you might understand why the Circle Method of drawing Arcs is inconsistent with the Trig Functions and how they get plotted (ie crazy!).

OK Bill's first issue might be better understood that Basic's Y axis does not increase going up screen like it does in all Math and Physics.

But as x increase from 0 to 90 and beyond the plot of Trig functions sin and cos do go clock-wise consistent to a proper reflection of y axis going down screen as it increases. So the plots go counter-clock if the y axis goes up and clockwise reflection when flip y axis.

Bill reversed his plotting by using special conversion functions of x, y... but he could'a, should'a used Window to reset the direction of axis. And then the battle would be carried to the Circle command doing Arcs.

Bill also trying to maintain the Right hand Rule for 3rd Dimension and pointing of Z axis positive side. 

It really gets confusing when Circle's arcs go in the inconsistent opposite direction to the trig functions. To Bill they probably looked like. "Good at least that's right ie (no need to run x, y's through conversion functions)".

i don't know what was the thinking or lack of 
1. leaving out fill circle 
2. not doing arcs consistently with Trig function plotting

Possibly it was an attempt to keep new versions compatible with old and another QWERTY inefficiency carried into the future.

New and Improved

Spinner 2

QB64
'Option _Explicit
_Title "Spinner 2" 'b+ 2021-06-18

' 2023-09-25 convert to QBJS
' 2023-09-27 use FArc for Fat Arcs!

$If WEB Then
       import G2D From "lib/graphics/2d.bas"
$End If

Dim As Long b, r
Dim a
Dim K As _Unsigned Long
Screen _NewImage(500, 500, 32)

While 1
   Cls
   b = b + 1
   For r = 10 To 200 Step 10 ' tsh73 suggested fix for inner most
       a = _D2R(b * r / 20)
       If Int(r / 10) Mod 2 Then K = &HFF009900 Else K = &HFF0000FF
       FArc 250, 250, r, 3, a, a + _Pi, K
   Next
   _Display
   _Limit 20 ' slowed down for QBJS
Wend

'2023-02-04 Fill Arc draw an arc with thickness, tested in Profile Pong 3-0
' this sub needs sub FCirc(CX As Long, CY As Long, R As Long, C As _Unsigned Long) for dots
Sub FArc (x, y, r, thickness, RadianStart, RadianStop, c As _Unsigned Long)
   Dim al, a
   'x, y origin of arc, r = radius, thickness is radius of dots, c = color
   'RadianStart is first angle clockwise from due East = 0 in Radians
   ' arc will start drawing there and clockwise until RadianStop angle reached

   If RadianStop < RadianStart Then
       FArc x, y, r, thickness, RadianStart, _Pi(2), c
       FArc x, y, r, 0, thickness, RadianStop, c
   Else
       al = _Pi * r * r * (RadianStop - RadianStart) / _Pi(2)
       For a = RadianStart To RadianStop Step 1 / r
           FCirc x + r * Cos(a), y + r * Sin(a), thickness, c
       Next
   End If
End Sub

' modified for QBJS AND QB64
Sub FCirc (CX As Long, CY As Long, R As Long, C As _Unsigned Long)

   ' put this at top of QB64 to QBJS code
   '$If WEB Then
   '        import G2D From "lib/graphics/2d.bas"
   '$End If


   $If WEB Then
           G2D.FillCircle CX, CY, R, C
   $Else
       Dim Radius As Long, RadiusError As Long
       Dim X As Long, Y As Long
       Radius = Abs(R): RadiusError = -Radius: X = Radius: Y = 0
       If Radius = 0 Then PSet (CX, CY), C: Exit Sub
       Line (CX - X, CY)-(CX + X, CY), C, BF
       While X > Y
           RadiusError = RadiusError + Y * 2 + 1
           If RadiusError >= 0 Then
               If X <> Y + 1 Then
                   Line (CX - Y, CY - X)-(CX + Y, CY - X), C, BF
                   Line (CX - Y, CY + X)-(CX + Y, CY + X), C, BF
               End If
               X = X - 1
               RadiusError = RadiusError - X * 2
           End If
           Y = Y + 1
           Line (CX - X, CY - Y)-(CX + X, CY - Y), C, BF
           Line (CX - X, CY + Y)-(CX + X, CY + Y), C, BF
       Wend
   $End If
End Sub


[qbjs]https://qbjs.org/?code=J09wdGlvbiBfRXhwbGljaXQKX1RpdGxlICJTcGlubmVyIDIiICdiKyAyMDIxLTA2LTE4CgonxA4zLTA5LTI1IGNvbnZlcnQgdG8gUUJKU8wdNyB1c2UgRkFyYyBmb3IgRmF0IEFyY3MhCgokSWYgV0VCIFRoZW4KIMcBaW1wb3J0IEcyRCBGcm9tICJsaWIvZ3JhcGhpY3MvMmQuYmFzIgokRW5kIElmCgpEaW0gQXMgTG9uZyBiLCByxRFhxQZLxBlfVW5zaWduZWTFIwpTY3JlZW4gX05ld0ltYWdlKDUwMCwgxQUzMikKCldoaWxlIDHlAI5DbHPFCGIgPSBiICvHFkZvciByID0gMTAgVG8gMjAwIFN0ZXDEDycgdHNoNzMgc3VnZ2VzdGVkIGZpeOUA9OYBRG1vc3TpAOdhID0gX0QyUihiICogciAvIDIwKckdSWYgSW50KMQXMTApIE1vZCAy5QEmIEsgPSAmSEZGMDA5OTAwIEVsc2XLFDAwRkbJReUBcjI1MCzGBXIsIDMsIGEsIGEgKyBfUGksIEvFK05leOYAll9EaXNwbGF5xg1MaW1pdCAy5ADWc2xvd2VkIGRvd27lAM7lAeFXZW5kCgon5gHmMi0wNCBGaWxs5AHaIGRyYXcgYW4gYXJjIHdpdGggdGhpY2tuZXNzLCB05gEZaW4gUHJvZuQBbFDkAbozLTAKJ8QocyBzdWIgbmVlZMYKRkNpcmMoQ1joAeQsIENZygxSyxfyAe0p5QCuZG90cwpTxEvkAJwoeCwgeeUBDesAlVJhZGlhblN0YXJ0yg1vcCwgY9NV5QEf5QJlbCwgYcUOJ8RVIG9yaWdpbiBvZuQA+SzlAiRyYWRpdeQA9shsIGlzxxXEKOQAm8RlPSBjb2xvcsZM6wCNxC5maXJzdCBhbmdsZSBjbG9ja3dpc2UgZuQDGmR1ZSBFYXN0ID0gMOQBUsY65gK0J+cBfmxsIHPFS+QBlWluZyB0aGVyZSBhbmTLTnVudGls6wD5x29yZWFjaGVkCsVRSWbMITzJDcRc7QPA5QFn/wFmLOQCgSgyKSwgY9c4MNU75QGUxTLkAvnJO2Fs5ANNUGnlA0rGBCjKMyAtzHspIC/Hfcp6b3LlA4/LJuQD28tC5gPiIC8g5gGkyTnkAp0geCArxXNDb3MoYSnkAgrGEFNpbsUQ6wDI6gDu6QN25wTIxAdTdWLkBVZtb2RpZmnkBD7nA2wgQU5EIFFCNjTmAsfFdf8DE/kDE+YBzScgcHV05gNvYeQFtHDkAo7EYugFwCBjb2TmAWAn8QWlJ+gAxP8FqucFqsZF6AWvxQ/RU8gBRzJELuQER+QA42xlIENY5ADcLCBSLCBDxjntAffkA4XkAaV1c+sA/8UQRXJyb3LIFc0w6wE26QE1ySHHTT0gQWJzKFIpOs1OPSAtxg86IFjnAi3EDFnkA37JQucDJsVFMOYFslBTZXTkAa/kAMspLCBDOiBFeGl05QHtyDZMaW5lxCMgLSDGJy3EDSvHDSwgQywgQuoF2OYGo1ggPiBZyRTqAL7oAK3MDisgWSAqIDLpBsPxAK7GJz7oALTNJccpWCA8PiBZxEPWI8QB6wDIWeUCli0gWOgAzMoR8ADQ3UIr0ELEEdhC5wJl0BfkAa/EUu4A/cQB+gEzLSBY5AEzzTLTX+QB/uUBFc0W8AHQ5ADO7QHUxRH0AMbROivQOsQR0DrlB4zECegDZ+gETg==[/qbjs]