Mandala Life Eternal Border Seed

Here is old, old favorite of mine with a recent update that does not blink the border on/off.

Mandala Life is a variation on Conway's Game of Life that colors according to neighbor count of cell and lives and dies by non Classic Rule Set going for 2 way symmetry of Mandala designs.

Option _Explicit
_Title "Mandala Life trans from sb" 'b+ 2023-01-15
'Mandala life.bas SmallBASIC (not MS) B+ for Bpf 2015-03-25
Screen _NewImage(600, 600, 12)
Dim As Long an, s, bigblock, g, x, y, pc, lc, cl
an = 60: s = 10: bigblock = 600: g = 0
Dim As Long a(1 To an, 1 To an), ng(1 To an, 1 To an), ls(1 To an, 1 To an)
Dim r$

While _KeyDown(27) = 0
   'If g Mod 2 = 0 Then ' keep a pulsing border
       For x = 1 To an
           a(x, 1) = 1: a(x, an) = 1: a(1, x) = 1: a(an, x) = 1
       Next
   'End If
   For x = 2 To an - 1
       For y = 2 To an - 1
           pc = a(x - 1, y - 1) + a(x - 1, y) + a(x - 1, y + 1) + a(x, y - 1) + a(x, y + 1) + a(x + 1, y - 1) + a(x + 1, y) + a(x + 1, y + 1)
           ls(x, y) = pc: r$ = _Trim$(Str$(pc))
           If a(x, y) Then
               If InStr("2346", r$) Then ng(x, y) = 1 Else ng(x, y) = 0
           Else 'birth?
               If InStr("34", r$) Then ng(x, y) = 1 Else ng(x, y) = 0
           End If
       Next
   Next
   Line (1, 1)-(bigblock, bigblock), 15, BF
   For y = 1 To an
       For x = 1 To an
           If a(x, y) Then
               Line ((x - 1) * s + 1, (y - 1) * s + 1)-Step(s, s), 0, BF
           Else
               lc = ls(x, y)
               Select Case lc
                   Case 0: cl = 15 'br white
                   Case 1: cl = 11 'cyan
                   Case 2: cl = 7 'low white, br gray
                   Case 3: cl = 10 'light green
                   Case 4: cl = 9 'blue
                   Case 5: cl = 13 'violet
                   Case 6: cl = 12 'br red
                   Case 7: cl = 4 'dark red
                   Case 8: cl = 1 'indigo
               End Select
               Line ((x - 1) * s + 1, (y - 1) * s + 1)-Step(s, s), cl, BF
           End If
       Next
   Next
   For y = 1 To an
       For x = 1 To an
           a(x, y) = ng(x, y)
       Next
   Next
   g = g + 1
   If g > 60 Then _delay .25

Wend


Seen here!
qbjs.org/index.html?code=T3B0aW9uIF9FeHBsaWNpdApfVGl0bGUgIk1hbmRhbGEgTGlmZSB0cmFucyBmcm9tIHNiIiAnYisgMjAyMy0wMS0xNQonyCxsaWZlLmJhcyBTbWFsbEJBU0lDIChub3QgTVMpIEIrIGZvciBCcGYgMjAxNS0wMy0yNQpTY3JlZW4gX05ld0ltYWdlKDYwMCwgxQUxMikKRGltIEFzIExvbmcgYW4sIHMsIGJpZ2Jsb2NrLCBnLCB4LCB5LCBwYywgbGMsIGNsCmFuID0gNjA6IHMgPSAxMDrJL8UXMDogZyA9IDDOWCgxIFRvxV/HCSksIG5n1BZsc9IWxUxyJAoKV2hpbGUgX0tleURvd24oMjcpxWsgICAgJ0lmIGcgTW9kIDLEFCBUaGVuICcga2VlcCBhIHB1bHNpbmcgYm9yZGVyxTHEAUZvciB45ADGxmnJGMQBYSh4LCAxxGExOsYNYW7JDjEsIHjJDeQAq8YOyUFOZXh0xQ0nRW5kIElmxQzIbjLGbiAtyzHEHHnXHMQBcGMgPeQAhsQZLCB5xAcpICvLEs4OICvJIM4uzhzEC89OxhLPIMQy7QCPbHPFS+QA9XBjOiByJCA9IF9UcmltJChTdHIkKHBjKc4xSWbHfinlAZrNHMcgSW5TdHIoIjIzNDYiLCByJMYq5AInyGsxIEVsc2XMEuYB/MgBxR4nYmlydGg/22IzNN9g2WDqAczEAekB5ckJTGluZSDkAh0xKS0o6gNGyAopLCAxNSwgQkbpAg/kAfPwAn38ApX/AUfnAIHmAgcpICogc+YBwijnAePHESktU3RlcChzLCBzKSwgMOkAksgB5AEG0Vts5AKC6AH40R5TZWxlY3QgQ2FzZSBsY9EfxAHFHDA6IGNs5ADdNSAnYnIgd2hpdNJryS4xyC4xICdjee8BDM0qMscqNyAnbG93xlgsIGJyIGdyYXnaNzPIYTAgJ2xpZ2h0IGfkBS3aMTTHMTkgJ2JsdfsAuzXIWjMgJ3Zpb2xl5gIi1Sw2yCwy5QEVcmVk2iw3xyw0ICdkYXJr3i04yFkgJ2luZGlnb9Er5ALT5gG8/wJM/wJM5wJMY2zyAk3/AzX/AwjSGMQB6AMFPekDrdth5AaQZ+QArMUO5QYoPiA25wYjX2RlbGF5IC4yNQoKV2VuZAo=

Use to have a smaller one of these as my avatar