QB45 program copied from document has errors

Any comment including negative ones are welcome.

I commented out all the "Print XX 'debug" lines in the file you pasted. The program still thinks the input file "ATF.s2p" is bad, "Error: Didn't find 9 numbers parsing the following data line: "

All the variants of the program seem to process the last "If CH$" line wrong. It may be processing the first "If CH$" line wrong as well. 

The original program, S2P2LIB1.bas the line is:
If CH$ = "" And SP = 0 Then D(k) = Val(D$): k = k + 1: SP = 1: D$ = " "

The program thinks "ATF.s2p" is bad when it isn't. That's when I added all the "Print" debug lines hoping to spot what is wrong. For one, k never increments above 1. It should be 1-9 and 10 drops to End Sub.

I think CH$ = "" is a typo in the PDF so I modified the line to be:
If CH$ = " " And SP = 0 Then D(k) = Val(D$): k = k + 1: SP = 1: D$ = " "

Unfortunately changing CH$ = "" to CH$ = " " caused the "subscript out of range" error. If you ignore the error, k does increment but there is still something wrong with this line.

FYI

ATF.s2p is a simplified files with only 1 line of data. A real file would have many lines of data.

k = count of numbers in each line of the file, ATF.s2p. The count should be 9 like shown below. k is supposed to increment from 1-9 and 10 drops to End Sub. This causes the next line in the file to be read.
1.0 0.93 -41 5.58 143 0.050 71 0.45 -23

SP = " " or Spaces

L$ = Line of data in ATF.s2p as it's being "processed". Since ATF.s2p only has one line, L$=1.0 0.93 -41 5.58 143 0.050 71 0.45 -23


CH = number count

CH$ = character, For above line of data, CH$=1 CH$=. CH$=0 CH$= "blank"

Yes

I have an alternate program and confirmed the output is correct.

I will look at the changes you made.

Thank You!

Well that didn't take long:
Option _Explicit ' lets see what needs DIM
'$Debug
'S2P2LIB1-- converts S2P tables to PSpice-compatible frequency-response tables.
'Written in QuickBASIC (v4.5). See 'HelpMessage' SUB for additional comments.
'DECLARE SUB ParseDataLine ()  ' dont need this
'DECLARE SUB HelpMessage ()     ' ditto
'Dim D(16), M(50, 9)

ReDim Shared D(1 To 16) ' <<<< REDIM to make D a dynamic array
Dim Shared M(50, 9) ' As Single >> ditto
Dim Shared L$ ' <<<<<<<<<<<<<<<<<<<<<<<<<<<<<  this needs to get into Parse Sub
'Common Shared D(), M(), L$  ' >>>>> let do this without Common and before Dim them

Dim As Long False, True, DataLine, EODat, InTheData, k, p, offSet, F
Dim C$, ufn$, HDR$, G$, M$, p$
Dim S$(1 To 4), E$(1 To 4)
Dim As Single prevPH, PH, UWP, DB

False = 0: True = Not False
DataLine = 0: EODat = False
'C$ = Command$   ' needs changes so Help screens are displayed
C$ = "ATF.s2p" 'Decomment and edit in uncompiled version.
If UCase$(Right$(C$, 4)) = ".S2P" Then 'Plausible command$ found.
   ufn$ = Left$(C$, Len(C$) - 4)
Else
   Call HelpMessage ': System
End If
Open C$ For Input As #1
Open ufn$ + ".LIB" For Output As #2
Print #2, ".SUBCKT " + ufn$ + " 1 2 3; Port1 Port2 Common"
Print #2, "*Subcircuit generated by S2P2LIB1.EXE on " + Date$
While Not (EOF(1) Or EODat)
   Line Input #1, L$
   L$ = LTrim$(L$) 'Get rid of any leading spaces.
   If Left$(L$, 1) = "!" Then Print #2, "*" + Right$(L$ + " ", Len(L$))
   If Left$(L$, 1) = "#" Then HDR$ = UCase$(L$): Print #2, "*" + L$
   If Val(L$) > 0 Then
       InTheData = True
       ParseDataLine ' loads D() with file numbers
       DataLine = DataLine + 1
       For k = 1 To 9: M(DataLine, k) = D(k): Next
   End If
   If Val(L$) = 0 And InTheData = True Then EODat = True
Wend
Close #1
Print #2, " ": Print #2, "R1N 1 5 -50": Print #2, "R1P 5 7 100"
Print #2, "R2N 2 4 -50": Print #2, "R2P 4 6 100"
S$(1) = "*S11 FREQ DB PHASE": S$(2) = "*S21 FREQ DB PHASE"
S$(3) = "*S12 FREQ DB PHASE": S$(4) = "*S22 FREQ DB PHASE"
E$(1) = "E11 7 9 FREQ {V(5,3)}=": E$(2) = "E21 6 8 FREQ {V(5,3)}="
E$(3) = "E12 9 3 FREQ {V(4,3)}=": E$(4) = "E22 8 3 FREQ {V(4,3)}="
G$ = "_+_(###.##gHz_,+###.##_, +###.##)" 'Format for gHz data
M$ = "_+_(#####.##MHz_,+###.##_, +###.##)" 'Format for MHz data
If InStr(HDR$, "MHZ") Then p$ = M$ Else p$ = G$
For p = 1 To 4 'Build S11, S21, S12, and S22 blocks in sequence.
   Print #2, " ": Print #2, S$(p): Print #2, E$(p)
   offSet = 0: prevPH = 0 'Clear variables used to unwrap phase.
   For F = 1 To DataLine 'Successive frequency values.
       PH = M(F, 2 * p + 1) 'Current phase data.
       If Abs(PH - prevPH) > 180 Then offSet = offSet - 360 * Sgn(PH - prevPH)
       prevPH = PH
       UWP = PH + offSet 'UnWrapped Phase.
       DB = 20 * Log(M(F, 2 * p)) / Log(10): 'Convert magnitude to DB values.
       Print #2, Using p$; M(F, 1); DB; UWP
       Print "."; 'Something to look at.
Next F: Next p
Print #2, " ": Print #2, ".ENDS"
Print "Finished. Result saved in file "; ufn$; ".LIB"
Close #2
End

Sub HelpMessage
   Print "WBA 7/94. This utility converts an S-parameter file *.S2P having"
   Print "a magnitude and angle (degrees) format into a PSPICE subcircuit"
   Print "file *.LIB which uses the Analog Behavioral Model option."
   Print "The source file should be in the current directory."
   Print "A 50 ohm reference impedance is assumed."
   Print "GHz frequency units are assumed unless the *.S2P files contains"
   Print "a header record beginning with '#' and followed by 'MHz'"
   Print " "
   Print "USAGE: S2P2LIB *.S2P "
End Sub

Sub ParseDataLine
   Dim As Long i, spaceF, j
   Dim b$, c$
   For i = 1 To Len(L$)
       c$ = Mid$(L$, i, 1)
       If c$ = " " Then
           If spaceF Then
               ' skip it! already have space
           Else
               j = j + 1 ' we have data item
               D(j) = Val(b$)
               b$ = ""
               spaceF = 1
           End If
       Else
           b$ = b$ + c$: spaceF = 0 ' building a number
       End If
   Next
   If Len(b$) Then ' handle left overs
       j = j + 1 ' we have data item
       D(j) = Val(b$)
   End If

   Print "check data:"
   For i = 1 To j
       Print i, D(i)
   Next
End Sub


Definitely nicer as D() is loaded directly and Split sub not needed.

OK easy fix, that other data file had 75 lines of data and M() was only setup for 50. I switched it to 100 and changed the file to BFP780.s2p
It ran fine here are results: