Snake Game (Nibbles)

man oh man, I've done so much stuff with Snake Game variations !!!

let me give you, AP, a couple samples and maybe you can figure out how your code differs from proper functioning code faster than i, i will bet on that

here is one in ascii the shortest version i have, i think

_Title "a simple snake game"
Screen 12
Randomize Timer

While 1
   Dim snake(1 To 500, 0 To 1) As Integer
   x = 15: y = 3: died = 0
   fy = Int(Rnd * 26) + 3: fx = Int(Rnd * 75) + 3
   While fx = x And fy = y
       fy = Int(Rnd * 26) + 3: fx = Int(Rnd * 75) + 3
   Wend
   yd = 1: xd = 0: snakeLength = 1
   Do

       keypress$ = InKey$
       If keypress$ = Chr$(0) + Chr$(72) Then 'up
           If yd = 1 Then died = -1 Else xd = 0: yd = -1
       ElseIf keypress$ = Chr$(0) + Chr$(80) Then 'down
           If yd = -1 Then died = -1 Else xd = 0: yd = 1
       ElseIf keypress$ = Chr$(0) + Chr$(77) Then 'right
           If xd = -1 Then died = -1 Else xd = 1: yd = 0
       ElseIf keypress$ = Chr$(0) + Chr$(75) Then 'left
           If xd = 1 Then died = -1 Else xd = -1: yd = 0
       End If

       'update x, y
       x = x + xd
       y = y + yd

       'did snake just die   by hitting wall /boundry?
       If x < 3 Or x > 77 Then died = -1
       If y < 2 Or y > 28 Then died = -1

       ' did  snake run into itself
       For sn = 2 To snakeLength
           If y = snake(sn, 0) And x = snake(sn, 1) Then died = -1
       Next

       'did snake eat frut
       If x = fx And y = fy Then
           While fx = x And fy = y
               fy = Int(Rnd * 26) + 3: fx = Int(Rnd * 75) + 3
           Wend
           snakeLength = snakeLength + 1
       End If

       'did snake disappear into worm hole
       If (x = 5 And y = 5) Or (x = 73 And y = 5) Or (x = 73 And y = 23) Or (x = 5 And y = 23) Then
           x = 40: y = 14
       End If

       If died Then Exit Do

       Cls
       'show garden
       Line (10, 14)-(616, 448), 15, B

       'show frut
       Color 13: Locate fy, fx: Print "F"
       'show snake
       Color 10
       snake(1, 0) = y: snake(1, 1) = x
       For sn = snakeLength To 1 Step -1
           snake(sn + 1, 0) = snake(sn, 0): snake(sn + 1, 1) = snake(sn, 1)
           Locate snake(sn, 0), snake(sn, 1): Print "s"
       Next
       snake(1, 0) = y: snake(1, 1) = x
       Locate y, x: Print "S"

       _Display
       _Limit 5 'for starters
   Loop Until keypress$ = Chr$(27)
   _Delay 3
Wend


here is one fellippe did that i modified to shorten it

'''$NOPREFIX  2020-03-11 b+ Mod Fellippe's Simple Snake: https://www.qb64.org/forum/index.php?topic=2317.0
' I am curious if I can gett snake timing better
' changes
' loose  $NOPREFIX and replace _
' loose TYPE  fix trail to trailX(), trailY()
' loose canvas direct screen with xmax X ymax dimensions
Option _Explicit
Const sps = 20, sq = 20
Const xmax = sps * sq, ymax = xmax

Screen _NewImage(400, 400, 32)

_Title "Simplest snake b+ mod Fellippe's 2020-03-11"
Dim px, py, ax, ay, xv, yv, tail, i, keypress$
Dim trailX(1000), trailY(1000)
px = 10
py = 10
ax = 15
ay = 15
tail = 1

For i = 0 To tail - 1
   trailX(i) = px
   trailY(i) = py
   px = px + 1
Next

Do

   'bg
   Line (0, 0)-(_Width, _Height), _RGB32(0), BF

   'snake
   For i = 0 To tail - 1
       Line (trailX(i) * sq, trailY(i) * sq)-Step(sq - 2, sq - 2), _RGB32(55, 161, 61), BF
       'IF trailX(i) = px AND trailY(i) = py THEN tail = 1
   Next


   'apple
   If (ax = px And ay = py) Then
       tail = tail + 1
       ax = Int(Rnd * sps)
       ay = Int(Rnd * sps)
   End If

   Line (ax * sq, ay * sq)-Step(sq - 2, sq - 2), _RGB32(255, 0, 0), BF
   '>>>>>>>>>>>>>>>>>>>>> The snake really does have to die if it's headed back into it's body
   'don't die if reverse key press but don't do it either!
   keypress$ = InKey$
   If keypress$ = Chr$(0) + Chr$(72) Then 'up
       If yv <> 1 Then xv = 0: yv = -1
   ElseIf keypress$ = Chr$(0) + Chr$(80) Then 'down
       If yv <> -1 Then xv = 0: yv = 1
   ElseIf keypress$ = Chr$(0) + Chr$(77) Then 'right
       If xv <> -1 Then xv = 1: yv = 0
   ElseIf keypress$ = Chr$(0) + Chr$(75) Then 'left
       If xv <> 1 Then xv = -1: yv = 0
   ElseIf keypress$ = "q" Or keypress$ = Chr$(27) Then
       End '>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> here is quit or escape clause!!!!
   End If
   _KeyClear
   px = px + xv
   py = py + yv

   If px < 0 Then px = sps - 1
   If px > sps - 1 Then px = 0
   If py < 0 Then py = sps - 1
   If py > sps - 1 Then py = 0

   trailX(tail) = px
   trailY(tail) = py
   For i = 0 To tail - 1
       trailX(i) = trailX(i + 1): trailY(i) = trailY(i + 1)
   Next
   _Display
   _Limit 3
Loop


don't like key action on this, you have to turn the snake 1 block before the row or column plus this one doesn't crash when go through a wall it comes back on the other side.

i will check your code out to see what i can find, when i have more time.

i even have a snake game with ai, it runs and runs until the screen is full of snake, pretty cool, got to go now... be back later