Help with DECLARE/usage of GetDiskFreeSpaceExA

> {code}
What fabulous code! You should call yourself APIMAN!
I took the liberty of turning your code into a subroutine.

THANKS!

Declare Library
 Function GetDriveTypeA& (nDrive As String)
 Function GetLogicalDriveStringsA& (ByVal nBuff As Long, lpbuff As String)
End Declare
Declare Dynamic Library "Kernel32"
 Function GetVolumeInformationA& ( _
   Drive As String, Label As String, Byval nVol As Long, Byval Serial As _Offset, _
   Byval Max As _Offset, Byval Flags As _Offset, Sys As String, Byval nSys As Long)
 Function GetDiskFreeSpaceA& (_
   nDrive As String, Byval csectors As _Offset, Byval sbytes As _Offset, Byval cfree As _Offset, Byval ctotal As _Offset)
End Declare

Screen _NewImage(1024, 768, 256)
Call Sub1("C:\" + Chr$(0))
Call Sub1("D:\" + Chr$(0))
Call Sub1("E:\" + Chr$(0))
Call Sub1("X:\" + Chr$(0))
Call Sub1("Y:\" + Chr$(0))
Call Sub1("Z:\" + Chr$(0))

Sub Sub1 (Drive As String)
 Dim DriveType As Long
 Dim Label As String, Sys As String, ret As Long
 Dim Serial As Long, nMax As Long, nFlags As Long
 Dim csectors As Long, sbytes As Long, cfree As Long, ctotal As Long

 DriveType = GetDriveTypeA(Drive)
 Label = Space$(20)
 Sys = Space$(20)
 ret = GetVolumeInformationA(Drive, Label, Len(Label), _Offset(Serial), _Offset(nMax), _Offset(nFlags), Sys, Len(Sys))
 If ret > 0 Then ret = GetDiskFreeSpaceA(Drive, _Offset(csectors), _Offset(sbytes), _Offset(cfree), _Offset(ctotal))
 If ret > 0 Then
   bpc~&& = csectors * sbytes
   sType$ = "Unknown  NoRoot   RemovableLocal    Network  CD       Ramdisk  "
   Print Drive
   Print "Size ="; Using "##,###,###,###,###"; ctotal * bpc~&&
   Print "VolumeName = "; Left$(Label, _InStrRev(Label, Chr$(0)) - 1)
   Print "Serial = "; Hex$(Serial)
   Print "DriveType = "; Mid$(sType$, DriveType * 9 + 1, 9)
   Print "FileSystem = "; Left$(Sys, _InStrRev(Sys, Chr$(0)) - 1)
   Print "FreeSpace = "; Using "##,###,###,###,###"; cfree * bpc~&&
   Print
 End If
End Sub



> "confusion"
I certainly don't understand all I know about API's, but this seems to work.  I had to take out "ByVal" on lpDirectoryName.  I hope this doesn't break our computers.

Declare Dynamic Library "kernel32" '
 Function GetDiskFreeSpaceEx& Alias "GetDiskFreeSpaceExA" ( _
   lpDirectoryName As String, _
   lpFreeBytesAvailableToCaller As _INTEGER64, _
   lpTotalNumberOfBytes As _INTEGER64, _
   lpTotalNumberOfFreeBytes As _INTEGER64)
End Declare

Screen _NewImage(1024, 768, 256)
Call Sub1("C:\" + Chr$(0))
Call Sub1("E:\" + Chr$(0))

Sub Sub1 (DirName As String)
 Dim FreeBytesToCaller As _Integer64
 Dim TotalBytes As _Integer64
 Dim TotalFreeBytes As _Integer64
 Print DirName
 ret = GetDiskFreeSpaceEx(DirName, FreeBytesToCaller, TotalBytes, TotalFreeBytes)
 If ret > 0 Then
   Print "FreeBytesToCaller ="; Using "##,###,###,###,###"; FreeBytesToCaller
   Print "TotalBytes ="; Using "##,###,###,###,###"; TotalBytes
   Print "TotalFreeBytes ="; Using "##,###,###,###,###"; TotalFreeBytes
 End If
 Print
End Sub

I didn't bother to fix the other functions but I'd recommend checking the Wiki on your GitHub. The information on that page is incomplete but will at least give some help. Also, please check this MSDN page on data types.
LPCSTR = pointer to a string = _OFFSET(string$)
PULARGE_INTEGER = pointer to an unsigned int64 = _OFFSET(int64~&&)

Option _Explicit

$Console:Only



Declare Dynamic Library "Kernel32"

   Function GetDiskFreeSpaceEx& Alias "GetDiskFreeSpaceExA" (ByVal lpDirectoryName As _Offset, Byval lpFreeBytesAvailableToCaller As _Offset, Byval lpTotalNumberOfBytes As _Offset, Byval lpTotalNumberOfFreeBytes As _Offset)

End Declare



Dim As String drive: drive = "C:\" + Chr$(0)

Dim As _Unsigned _Integer64 FreeBytesToCaller, TotalBytes, TotalFreeBytes



If GetDiskFreeSpaceEx(_Offset(drive), _Offset(FreeBytesToCaller), _Offset(TotalBytes), _Offset(TotalFreeBytes)) Then

   Print "FreeBytesToCaller ="; Using "##,###,###,###,###"; FreeBytesToCaller

   Print "TotalBytes ="; Using "##,###,###,###,###"; TotalBytes

   Print "TotalFreeBytes ="; Using "##,###,###,###,###"; TotalFreeBytes

End If


The offset is because it is PULARGE_INTEGER. Not ULARGE_INTEGER. The P tells you it is a pointer and the MSDN page tells you it is a pointer to the ULARGE_INTEGER. So you'd use an _OFFSET to _INTEGER64. Byval should be used as a rule when passing numeric data. It's especially important if the external library is a header file rather than a DLL. A DLL allows you to fudge a bit but I strongly recommend passing all numeric variables/constants as BYVAL. Only ones you wouldn't/couldn't use it on would be UDTs and strings. I typically pass a string as _OFFSET anyways just to be consistent but those are the ones you can fudge the most on, in my opinion.

But as a rule, any variable that starts with "p" or "lp" will be passed as an _OFFSET because "p" means pointer and "lp" means long pointer. Both are equal for our purposes. I do a lot with the WinAPI in QB64 and will gladly help out with anything you do with it.